mirror of
https://github.com/overte-org/overte.git
synced 2025-04-29 13:02:43 +02:00
0cc940d433
Said files are now buried under hidden/externals; the (phony) build targets still exist and are visible in the target dropdown, but this is filterable (in Xcode, dunno about Visual Studio (just start typing and a filter/search box comes up))
81 lines
No EOL
2.8 KiB
CMake
81 lines
No EOL
2.8 KiB
CMake
set(EXTERNAL_NAME bullet)
|
|
|
|
if (WIN32)
|
|
set(PLATFORM_CMAKE_ARGS "-DUSE_MSVC_RUNTIME_LIBRARY_DLL=1")
|
|
else ()
|
|
set(PLATFORM_CMAKE_ARGS "-DBUILD_SHARED_LIBS=1")
|
|
|
|
if (ANDROID)
|
|
list(APPEND PLATFORM_CMAKE_ARGS "-DCMAKE_TOOLCHAIN_FILE=${CMAKE_TOOLCHAIN_FILE}" "-DANDROID_NATIVE_API_LEVEL=19")
|
|
elseif (APPLE)
|
|
list(APPEND PLATFORM_CMAKE_ARGS "-DCMAKE_INSTALL_NAME_DIR=<INSTALL_DIR>/lib")
|
|
endif()
|
|
endif ()
|
|
|
|
include(ExternalProject)
|
|
|
|
if (WIN32)
|
|
ExternalProject_Add(
|
|
${EXTERNAL_NAME}
|
|
URL https://bullet.googlecode.com/files/bullet-2.82-r2704.zip
|
|
URL_MD5 f5e8914fc9064ad32e0d62d19d33d977
|
|
CMAKE_ARGS ${PLATFORM_CMAKE_ARGS} -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR> -DBUILD_EXTRAS=0 -DINSTALL_LIBS=1 -DBUILD_DEMOS=0 -DUSE_GLUT=0 -DUSE_DX11=0
|
|
LOG_DOWNLOAD 1
|
|
LOG_CONFIGURE 1
|
|
LOG_BUILD 1
|
|
BINARY_DIR ${EXTERNAL_PROJECT_PREFIX}/build
|
|
)
|
|
else ()
|
|
ExternalProject_Add(
|
|
${EXTERNAL_NAME}
|
|
URL http://bullet.googlecode.com/files/bullet-2.82-r2704.tgz
|
|
URL_MD5 70b3c8d202dee91a0854b4cbc88173e8
|
|
CMAKE_ARGS ${PLATFORM_CMAKE_ARGS} -DCMAKE_BUILD_TYPE=RelWithDebInfo -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR> -DBUILD_EXTRAS=0 -DINSTALL_LIBS=1 -DBUILD_DEMOS=0 -DUSE_GLUT=0
|
|
LOG_DOWNLOAD 1
|
|
LOG_CONFIGURE 1
|
|
LOG_BUILD 1
|
|
BINARY_DIR ${EXTERNAL_PROJECT_PREFIX}/build
|
|
)
|
|
endif ()
|
|
|
|
# Hide this external target (for ide users)
|
|
set_target_properties(${EXTERNAL_NAME} PROPERTIES FOLDER "hidden/externals")
|
|
|
|
ExternalProject_Get_Property(${EXTERNAL_NAME} INSTALL_DIR)
|
|
|
|
string(TOUPPER ${EXTERNAL_NAME} EXTERNAL_NAME_UPPER)
|
|
|
|
set(BULLET_LIB_DIR "${INSTALL_DIR}/lib")
|
|
|
|
if (APPLE OR UNIX OR ANDROID)
|
|
if (APPLE)
|
|
set(BULLET_LIB_EXT "dylib")
|
|
else ()
|
|
set(BULLET_LIB_EXT "so")
|
|
endif ()
|
|
|
|
set(LIB_PREFIX "lib")
|
|
elseif (WIN32)
|
|
set(BULLET_LIB_EXT "lib")
|
|
endif ()
|
|
|
|
if (DEFINED BULLET_LIB_EXT)
|
|
set(_BULLET_LIB_PAIRS "DYNAMICS_LIBRARY\;BulletDynamics" "COLLISION_LIBRARY\;BulletCollision" "MATH_LIBRARY\;LinearMath" "SOFTBODY_LIBRARY\;BulletSoftBody")
|
|
|
|
foreach(_LIB_PAIR ${_BULLET_LIB_PAIRS})
|
|
list(GET _LIB_PAIR 0 _LIB_VAR_NAME)
|
|
list(GET _LIB_PAIR 1 _LIB_NAME)
|
|
|
|
set(${EXTERNAL_NAME_UPPER}_${_LIB_VAR_NAME}_RELEASE ${BULLET_LIB_DIR}/${LIB_PREFIX}${_LIB_NAME}.${BULLET_LIB_EXT} CACHE FILEPATH "${_LIB_NAME} release library location")
|
|
|
|
if (WIN32)
|
|
set(${EXTERNAL_NAME_UPPER}_${_LIB_VAR_NAME}_DEBUG ${BULLET_LIB_DIR}/${LIB_PREFIX}${_LIB_NAME}_Debug.${BULLET_LIB_EXT} CACHE FILEPATH "${_LIB_NAME} debug library location")
|
|
else ()
|
|
set(${EXTERNAL_NAME_UPPER}_${_LIB_VAR_NAME}_DEBUG "" CACHE FILEPATH "${_LIB_NAME} debug library location")
|
|
endif ()
|
|
endforeach()
|
|
endif ()
|
|
|
|
if (DEFINED ${EXTERNAL_NAME_UPPER}_DYNAMICS_LIBRARY_RELEASE)
|
|
set(${EXTERNAL_NAME_UPPER}_INCLUDE_DIR ${INSTALL_DIR}/include/bullet CACHE PATH "Path to bullet include directory")
|
|
endif () |