mirror of
https://github.com/overte-org/overte.git
synced 2025-07-10 09:18:45 +02:00
94 lines
3.8 KiB
Text
94 lines
3.8 KiB
Text
<@include gpu/Config.slh@>
|
|
<$VERSION_HEADER$>
|
|
// Generated on <$_SCRIBE_DATE$>
|
|
//
|
|
// fxaa.frag
|
|
// fragment shader
|
|
//
|
|
// Created by Raffi Bedikian on 8/30/15
|
|
// Copyright 2015 High Fidelity, Inc.
|
|
//
|
|
// Distributed under the Apache License, Version 2.0.
|
|
// See the accompanying file LICENSE or http://www.apache.org/licenses/LICENSE-2.0.html
|
|
//
|
|
|
|
// FXAA shader, GLSL code adapted from:
|
|
// http://horde3d.org/wiki/index.php5?title=Shading_Technique_-_FXAA
|
|
// Whitepaper describing the technique:
|
|
// http://developer.download.nvidia.com/assets/gamedev/files/sdk/11/FXAA_WhitePaper.pdf
|
|
|
|
#ifdef GL_ES
|
|
precision mediump float;
|
|
precision mediump int;
|
|
#endif
|
|
|
|
uniform sampler2D colorTexture;
|
|
uniform vec2 texcoordOffset;
|
|
|
|
in vec2 varTexcoord;
|
|
out vec4 outFragColor;
|
|
|
|
void main() {
|
|
// filter width limit for dependent "two-tap" texture samples
|
|
float FXAA_SPAN_MAX = 8.0;
|
|
|
|
// local contrast multiplier for performing AA
|
|
// higher = sharper, but setting this value too high will cause near-vertical and near-horizontal edges to fail
|
|
// see "fxaaQualityEdgeThreshold"
|
|
float FXAA_REDUCE_MUL = 1.0 / 8.0;
|
|
|
|
// luminance threshold for processing dark colors
|
|
// see "fxaaQualityEdgeThresholdMin"
|
|
float FXAA_REDUCE_MIN = 1.0 / 128.0;
|
|
|
|
// fetch raw RGB values for nearby locations
|
|
// sampling pattern is "five on a die" (each diagonal direction and the center)
|
|
// computing the coordinates for these texture reads could be moved to the vertex shader for speed if needed
|
|
vec3 rgbNW = texture(colorTexture, varTexcoord + (vec2(-1.0, -1.0) * texcoordOffset)).xyz;
|
|
vec3 rgbNE = texture(colorTexture, varTexcoord + (vec2(+1.0, -1.0) * texcoordOffset)).xyz;
|
|
vec3 rgbSW = texture(colorTexture, varTexcoord + (vec2(-1.0, +1.0) * texcoordOffset)).xyz;
|
|
vec3 rgbSE = texture(colorTexture, varTexcoord + (vec2(+1.0, +1.0) * texcoordOffset)).xyz;
|
|
vec3 rgbM = texture(colorTexture, varTexcoord).xyz;
|
|
|
|
// convert RGB values to luminance
|
|
vec3 luma = vec3(0.299, 0.587, 0.114);
|
|
float lumaNW = dot(rgbNW, luma);
|
|
float lumaNE = dot(rgbNE, luma);
|
|
float lumaSW = dot(rgbSW, luma);
|
|
float lumaSE = dot(rgbSE, luma);
|
|
float lumaM = dot( rgbM, luma);
|
|
|
|
// luma range of local neighborhood
|
|
float lumaMin = min(lumaM, min(min(lumaNW, lumaNE), min(lumaSW, lumaSE)));
|
|
float lumaMax = max(lumaM, max(max(lumaNW, lumaNE), max(lumaSW, lumaSE)));
|
|
|
|
// direction perpendicular to local luma gradient
|
|
vec2 dir;
|
|
dir.x = -((lumaNW + lumaNE) - (lumaSW + lumaSE));
|
|
dir.y = ((lumaNW + lumaSW) - (lumaNE + lumaSE));
|
|
|
|
// compute clamped direction offset for additional "two-tap" samples
|
|
// longer vector = blurry, shorter vector = sharp
|
|
float dirReduce = max((lumaNW + lumaNE + lumaSW + lumaSE) * (0.25 * FXAA_REDUCE_MUL), FXAA_REDUCE_MIN);
|
|
float rcpDirMin = 1.0 / (min(abs(dir.x), abs(dir.y)) + dirReduce);
|
|
dir = min(vec2(FXAA_SPAN_MAX, FXAA_SPAN_MAX),
|
|
max(vec2(-FXAA_SPAN_MAX, -FXAA_SPAN_MAX), dir * rcpDirMin)) * texcoordOffset;
|
|
|
|
// perform additional texture sampling perpendicular to gradient
|
|
vec3 rgbA = (1.0 / 2.0) * (
|
|
texture(colorTexture, varTexcoord + dir * (1.0 / 3.0 - 0.5)).xyz +
|
|
texture(colorTexture, varTexcoord + dir * (2.0 / 3.0 - 0.5)).xyz);
|
|
vec3 rgbB = rgbA * (1.0 / 2.0) + (1.0 / 4.0) * (
|
|
texture(colorTexture, varTexcoord + dir * (0.0 / 3.0 - 0.5)).xyz +
|
|
texture(colorTexture, varTexcoord + dir * (3.0 / 3.0 - 0.5)).xyz);
|
|
float lumaB = dot(rgbB, luma);
|
|
|
|
// compare luma of new samples to the luma range of the original neighborhood
|
|
// if the new samples exceed this range, just use the first two samples instead of all four
|
|
if (lumaB < lumaMin || lumaB > lumaMax) {
|
|
outFragColor.xyz=rgbA;
|
|
} else {
|
|
outFragColor.xyz=rgbB;
|
|
}
|
|
outFragColor.a = 1.0;
|
|
}
|