buildscript {
    repositories {
        jcenter()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.0.1'
        classpath 'de.undercouch:gradle-download-task:3.3.0'
    }
}


import org.apache.tools.ant.taskdefs.condition.Os

def file='qt-5.9.3_linux_armv8-libcpp.tgz'
if (Os.isFamily(Os.FAMILY_MAC)) {
    file = 'qt-5.9.3_osx_armv8-libcpp.tgz'
} else if (Os.isFamily(Os.FAMILY_WINDOWS)) {
    file = 'qt-5.9.3_win_armv8-libcpp.tgz'
}

def url='https://hifi-public.s3.amazonaws.com/austin/android/' + file
def destFile = new File(HIFI_ANDROID_PRECOMPILED, file)

task downloadQt(type: de.undercouch.gradle.tasks.download.Download) {
    src url
    dest destFile
}

task extractQt(dependsOn: downloadQt, type: Copy) {
    from tarTree(resources.gzip(destFile))
    into new File(HIFI_ANDROID_PRECOMPILED, 'qt')
}

task copyQtJars(dependsOn: extractQt, type: Copy) {
    from HIFI_ANDROID_PRECOMPILED + '/qt/jar'
    include '*.jar'
    into HIFI_ANDROID_PRECOMPILED + '/jar'
}

task copyQtLibs(dependsOn: extractQt, type: Copy) {
    from HIFI_ANDROID_PRECOMPILED + '/qt/lib'
    include 'libQt5AndroidExtras.so'
    include 'libQt5Concurrent.so'
    include 'libQt5Core.so'
    include 'libQt5Gamepad.so'
    include 'libQt5Gui.so'
    include 'libQt5MultimediaQuick_p.so'
    include 'libQt5Multimedia.so'
    include 'libQt5Network.so'
    include 'libQt5OpenGL.so'
    include 'libQt5Qml.so'
    include 'libQt5QuickControls2.so'
    include 'libQt5QuickParticles.so'
    include 'libQt5Quick.so'
    include 'libQt5QuickTemplates2.so'
    include 'libQt5QuickWidgets.so'
    include 'libQt5Script.so'
    include 'libQt5ScriptTools.so'
    include 'libQt5Scxml.so'
    include 'libQt5Svg.so'
    include 'libQt5WebChannel.so'
    include 'libQt5WebSockets.so'
    include 'libQt5WebView.so'
    include 'libQt5Widgets.so'
    include 'libQt5XmlPatterns.so'
    include 'libQt5Xml.so'
    into HIFI_ANDROID_PRECOMPILED + '/jni/arm64-v8a'
}

task setupQt(dependsOn: [copyQtLibs, copyQtJars]) {
}