diff --git a/cmake/compiler.cmake b/cmake/compiler.cmake
index 6ff6fce1d8..927871773d 100644
--- a/cmake/compiler.cmake
+++ b/cmake/compiler.cmake
@@ -6,6 +6,10 @@ if (NOT "${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
   message( FATAL_ERROR "Only 64 bit builds supported." )
 endif()
 
+if (USE_CCACHE OR "$ENV{USE_CCACHE}")
+  configure_ccache()
+endif()
+
 if (WIN32)
   add_definitions(-DNOMINMAX -D_CRT_SECURE_NO_WARNINGS)
 
diff --git a/cmake/macros/ConfigureCCache.cmake b/cmake/macros/ConfigureCCache.cmake
new file mode 100644
index 0000000000..6107faaa21
--- /dev/null
+++ b/cmake/macros/ConfigureCCache.cmake
@@ -0,0 +1,45 @@
+#
+#  ConfigureCCache.cmake
+#  cmake/macros
+#
+#  Created by Clement Brisset on 10/10/18.
+#  Copyright 2018 High Fidelity, Inc.
+#
+#  Distributed under the Apache License, Version 2.0.
+#  See the accompanying file LICENSE or http:#www.apache.org/licenses/LICENSE-2.0.html
+#
+
+macro(configure_ccache)
+    find_program(CCACHE_PROGRAM ccache)
+    if(CCACHE_PROGRAM)
+        message(STATUS "Configuring ccache")
+
+        # Set up wrapper scripts
+        set(C_LAUNCHER   "${CCACHE_PROGRAM}")
+        set(CXX_LAUNCHER "${CCACHE_PROGRAM}")
+
+        set(LAUNCH_C_IN "${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/launch-c.in")
+        set(LAUNCH_CXX_IN "${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/launch-cxx.in")
+        set(LAUNCH_C "${CMAKE_BINARY_DIR}/CMakeFiles/launch-c")
+        set(LAUNCH_CXX "${CMAKE_BINARY_DIR}/CMakeFiles/launch-cxx")
+
+        configure_file(${LAUNCH_C_IN} ${LAUNCH_C})
+        configure_file(${LAUNCH_CXX_IN} ${LAUNCH_CXX})
+        execute_process(COMMAND chmod a+rx ${LAUNCH_C} ${LAUNCH_CXX})
+
+        if(CMAKE_GENERATOR STREQUAL "Xcode")
+            # Set Xcode project attributes to route compilation and linking
+            # through our scripts
+            set(CMAKE_XCODE_ATTRIBUTE_CC ${LAUNCH_C})
+            set(CMAKE_XCODE_ATTRIBUTE_CXX ${LAUNCH_CXX})
+            set(CMAKE_XCODE_ATTRIBUTE_LD ${LAUNCH_C})
+            set(CMAKE_XCODE_ATTRIBUTE_LDPLUSPLUS ${LAUNCH_CXX})
+        else()
+            # Support Unix Makefiles and Ninja
+            set(CMAKE_C_COMPILER_LAUNCHER ${LAUNCH_C})
+            set(CMAKE_CXX_COMPILER_LAUNCHER ${LAUNCH_CXX})
+        endif()
+    else()
+        message(WARNING "Could not find ccache")
+    endif()
+endmacro()
diff --git a/cmake/templates/launch-c.in b/cmake/templates/launch-c.in
new file mode 100644
index 0000000000..6c91d96dd9
--- /dev/null
+++ b/cmake/templates/launch-c.in
@@ -0,0 +1,12 @@
+#!/bin/sh
+
+# Xcode generator doesn't include the compiler as the
+# first argument, Ninja and Makefiles do. Handle both cases.
+if [[ "$1" = "${CMAKE_C_COMPILER}" ]] ; then
+    shift
+fi
+
+export CCACHE_CPP2=true
+export CCACHE_HARDLINK=true
+export CCACHE_SLOPPINESS=file_macro,time_macros,include_file_mtime,include_file_ctime,file_stat_matches
+exec "${C_LAUNCHER}" "${CMAKE_C_COMPILER}" "$@"
diff --git a/cmake/templates/launch-cxx.in b/cmake/templates/launch-cxx.in
new file mode 100644
index 0000000000..4215d89c80
--- /dev/null
+++ b/cmake/templates/launch-cxx.in
@@ -0,0 +1,12 @@
+#!/bin/sh
+
+# Xcode generator doesn't include the compiler as the
+# first argument, Ninja and Makefiles do. Handle both cases.
+if [[ "$1" = "${CMAKE_CXX_COMPILER}" ]] ; then
+    shift
+fi
+
+export CCACHE_CPP2=true
+export CCACHE_HARDLINK=true
+export CCACHE_SLOPPINESS=file_macro,time_macros,include_file_mtime,include_file_ctime,file_stat_matches
+exec "${CXX_LAUNCHER}" "${CMAKE_CXX_COMPILER}" "$@"